《The UVM Primer》8: Parameterized Class Definitions

在上一章, 我们创建了使用静态变量的类, 用来装狮子. 这个静态类很不错, 我们可以合理的运用全局资源了. 然而, 问题还是出现了.

我们要一个小鸡笼怎么办呢? 看 lion_cage 的代码, 我们会发现需要的 chicken_cage类跟 lion_cage 基本是一样的, 除了把队列的类型换成 chicken.

直觉是把狮子笼的代码拷出来弄一个小鸡笼. 不过这样犯了一个错误. 一个动物园要多烂才会只有狮子跟小鸡啊. 我们肯定是要为其他的动物准备不同的笼子. 然后我们还是拷代码?

可以想见的是很多情况下我们都会对笼子进行通用性的改动(比如添加一个 feed()方法),如果我们用的是代码拷贝, 这样要改动的话就需要每个地方都改. 这个很快就会失控, 之后我们不停的因为这些 bug 被问责.

幸运的是, SystemVerilog的"参数化类定义"可以解决这个问题. 更重要的是UVM里面大量的使用了这一套, 所以我们要把这个搞懂才行.

造一个动物cage

都还记得原来 Verilog 中的参数吧. 参数是我们在例化 module 的时候可以设置型的例子是存储器. 我们为数据总线和地址总线配置参数, 然后用户就可以在化任意容量的存储器了. 这里是个例子:

module RAM #(awidth, dwidth) (
       input wire [awidth-1:0] address, 
       inout wire [dwidth-1:0] data,
       input we);

   initial $display("awidth: %0d  dwidth %0d",awidth, dwidth);
   // code to implement RAM
endmodule // RAM

我们要用同样的方法来解决笼子的问题, 不过我们用参数指定类型. animal_cage 的代码跟 lion_cage 基本一样, 除了前者带有一个参数. 在第一行可以看见我们定义的 type 参数 T, 然后我们用这个参数来定义队列的类型, 并用作 cage_animal 的参数类型.

virtual class animal;
   protected int age=-1;
   protected string name;

   function new(int a, string n);
      age = a;
      name = n;
   endfunction : new

   function int get_age();
        return age;
   endfunction : get_age

   function string get_name();
      return name;
   endfunction : get_name

   pure virtual function void make_sound();


endclass : animal


class lion extends animal;

   protected string        name;

   function new(int age, string n);
      super.new(age, n);
   endfunction : new

   function void make_sound();
      $display ("The lion, %s, says Roar", get_name());
   endfunction : make_sound


endclass : lion


class chicken extends animal;

   function new(int age, string n);
      super.new(age, n);
   endfunction : new

   function void make_sound();
      $display ("The Chicken, %s, says BECAWW", get_name());
   endfunction : make_sound



endclass : chicken
        

class animal_cage #(type T);

   protected static T cage[$];

   static function void cage_animal(T l);
      cage.push_back(l);
   endfunction : cage_animal

   static function void list_animals();
      $display("Animals in cage:"); 
      foreach (cage[i])
        $display(cage[i].get_name());
   endfunction : list_animals

endclass : animal_cage

   

module top;


   initial begin
      lion   lion_h;
      chicken  chicken_h;
      lion_h = new(15, "Mustafa");
      animal_cage #(lion)::cage_animal(lion_h);
      lion_h = new(15, "Simba");
      animal_cage #(lion)::cage_animal(lion_h);

      chicken_h = new(1, "Clucker");
      animal_cage #(chicken)::cage_animal(chicken_h);
      chicken_h = new(1, "Scratchy");
      animal_cage #(chicken)::cage_animal(chicken_h);

      $display("-- Lions --");
      animal_cage #(lion)::list_animals();
      $display("-- Chickens --");
      animal_cage #(chicken)::list_animals();
   end

endmodule : top

现在我们可以用同样的代码为基础, 为不同的动物创建不同的笼子类, 在这里的修改会影响到所有的动物笼子.
这个例子展示了访问狮子笼和小鸡笼的方法. 我们把动物的类型方法#之后的括号里面.狮子的话我们用 lion 类作为参数来访问 cage_animal 静态方法. 小鸡的话就用 chicken 类作为参数来访问 cage_animal 静态方法.
最后我们得到两个静态队列, 一个存着狮子, 一个存着小鸡. 这推出了参数化类的一个重要性质. 每当例化一个参数化类, 你用不同的参数创建的类都是不同的. animal_cage#(lion)和 animal_cage#(chicken)是完全不同的命名空间下的类, 只不过代码是一样的.
你会注意到我们看到的不是一个笼子 4 个动物, 而是两个笼子, 每个笼子里有两个动物.狮子跟小鸡是分开的.
读到这里, 你们可能会觉得我们只能把参数化的类用在静态变量和静态方法上. 先不看这个, 我们来看另外一个造笼子的方法.

用参数来定义变量

UVM 里会用静态方法和参数, 或者两个混用, 不过 UVM 里面参数化类型用途最多的地方还是变量定义. 我们来改一下动物笼子来展示一下.这个例子中, 我们不用静态方法来访问动物笼子了, 我们要开始用例化的动物笼子对象来存放其他的动物. 
跟之前的唯一区别是上面的代码去掉了变量和方法之前的 static 关键字. 我们需要声明例化操作对象的变量. 
我们有了两个新变量: lion_cage 和 chicken_cage.
我们在声明变量的时候传入参数. 编译器根据传入的参数类型来生成一个新的类, 然后用来声明变量. 如果你用了跟动物笼子不匹配的类型, 比如说一个没有 get_name()方法的对象, 这样会得到语法错误.

virtual class animal;
   protected int age=-1;
   protected string name;

   function new(int a, string n);
      age = a;
      name = n;
   endfunction : new

   function int get_age();
        return age;
   endfunction : get_age

   function string get_name();
      return name;
   endfunction : get_name

   pure virtual function void make_sound();


endclass : animal


class lion extends animal;

   protected string        name;

   function new(int age, string n);
      super.new(age, n);
   endfunction : new

   function void make_sound();
      $display ("The lion, %s, says Roar", get_name());
   endfunction : make_sound


endclass : lion


class chicken extends animal;

   function new(int age, string n);
      super.new(age, n);
   endfunction : new

   function void make_sound();
      $display ("The Chicken, %s, says BECAWW", get_name());
   endfunction : make_sound



endclass : chicken
        

class animal_cage #(type T);

   protected T cage[$];

   function void cage_animal(T l);
      cage.push_back(l);
   endfunction : cage_animal

   function void list_animals();
      $display("Animals in cage:"); 
      foreach (cage[i])
        $display(cage[i].get_name());
   endfunction : list_animals

endclass : animal_cage

   

module top;
   
   lion   lion_h;
   chicken  chicken_h;

   animal_cage #(lion)  lion_cage;
   animal_cage #(chicken) chicken_cage;
  
   

   initial begin
      lion_cage = new();
      lion_h = new(15, "Mustafa");
      lion_cage.cage_animal(lion_h);
      lion_h = new(15, "Simba");
      lion_cage.cage_animal(lion_h);

      chicken_cage = new();
      chicken_h = new(1, "Little Red Hen");
      chicken_cage.cage_animal(chicken_h);

      chicken_h = new(1, "Lady Clucksalot");
      chicken_cage.cage_animal(chicken_h);
   

      $display("-- Lions --");
      lion_cage.list_animals();
      $display("-- Chickens --");
      chicken_cage.list_animals();
   end

endmodule : top

上面的代码例化了一个新的狮子笼对象, 新建了两个狮子(木莎法和辛巴), 然后关进笼子.接着是对小鸡进行一样的操作, 例化新的 chicken_cage 然后关进两只小鸡.
这个代码跟之前的效果是一样的, 一个大区别是我们不能在验证平台的任意位置访问笼子了. 我们创建了新的笼子对象然后放进动物, task 结束时, 对象就消失了.
在这章我们学习了 UVM 的基础: 参数化的类. 我们对 SystemVerilog 中的 OOP 已经了解的差不多了.
在下一章, 我们要把这些 OOP 特性集合起来, 实现一个 Factory 类. 因为 Factory 设计模式是 UVM 的一个关键部分, 这样的话我们就能了解这是怎么回事了.